modela	"Cylinder for VRML-MODELA bridge"
{
	smooth	vrml.cyl.smooth : model
	{
		// parts
		var		BOTTOM=true;
		var		SIDES=true;
		var		TOP=true;
		if	(vrml.cyl.parts%2=0)
		{
			BOTTOM=false;
		}
		if	(int (vrml.cyl.parts/2)%2=0)
		{
			SIDES=false;
		}
		if	(int (vrml.cyl.parts/4)%2=0)
		{
			TOP=false;
		}

		// MaterialBinding
		var		nmater=vrml.mater.num;
		if (!(vrml.matebnd.value=vrml.enum.PER_PART
			| vrml.matebnd.value=vrml.enum.PER_PART_INDEXED))
		{
			nmater=1;
		}

		var		t1, x1,z1;
		var		t2, x2,z2;

		sim		vrml.cyl.radius,vrml.cyl.height/2,vrml.cyl.radius;
		boundary	sphere	0,0,0, sqrt (3)
		{
			// poly-cylinder
			var		i=0;
			while	(i<vrml.cyl.pn)
			{
				t1=2*PI*i/vrml.cyl.pn;
				t2=2*PI*(i + 1)/vrml.cyl.pn;
				x1=cos (t1);
				z1=sin (t1);
				x2=cos (t2);
				z2=sin (t2);
				if	(SIDES)
				{
					attr	vrml_attr_#(0%nmater);
					poly	"SIDES"
					{
						pt	x1,1,z1;
						pt	x1,-1,z1;
						pt	x2,-1,z2;
						pt	x2,1,z2;
					}
				}
				if	(TOP)
				{
					attr	vrml_attr_#(1%nmater);
					poly	"TOP"
					{
						pt	0,1,0;
						pt	x1,1,z1;
						pt	x2,1,z2;
					}
				}
				if	(BOTTOM)
				{
					attr	vrml_attr_#(2%nmater);
					poly	"BOTTOM"
					{
						pt	0,-1,0;
						pt	x1,-1,z1;
						pt	x2,-1,z2;
					}
				}
				i=i + 1;
			}
		}
	}
}